While you can display the contents of a MEMO field in a TDBMemo component, by design the TDBGrid will only display "(Memo)" for the contents of such fields.

In order to actually display some text (from the MEMO field) in the appropriate DBGrid cell, you'll only need to add a simple line of code ...

For the purpose of the next discussion, let's say you have a database table named "TestTable" with at least one MEMO field named "Data".

OnGetText

1. Connect your TDataset descendant component (TTable, TQuery, TADOTable, TADOQuery ....) to the "TestTable" database table.
2. Double click the dataset component to open the Fields editor
3. Add the MEMO field to the list of persistent fields
4. Select the MEMO field in the Fields editor
5. Activate the Events tab in the Object Inspector
6. Double click the OnGetText event to create the event handler

procedure TForm1.DBTableDataGetText(
  Sender: TField;
  var Text: String;
  DisplayText: Boolean);
begin
  Text := Copy(DBTableData.AsString, 1, 50);
end;

Note: the dataset object is called "DBTable", the MEMO field is called "DATA", and therefore, by default, the TMemoField connected to the MEMO database field is called "DBTableData". By assigning DBTableData.AsString to the Text parameter of the OnGetText event, we tell Delphi to display ALL the text from the MEMO field in a DBGrid cell.
You can also adapt the DisplayWidth of the memo field to a more appropriate value.

Note: since MEMO fields can be quite BIG, it is a good idea to show only a part of it. In the above code, only the first 50 characters are displayed.

Editing on a separate form

procedure TForm1.DBGrid1KeyDown(
  Sender: TObject; 
  var Key: Word;
  Shift: TShiftState);
begin
  if Key = VK_RETURN then
  begin
    if DBGrid1.SelectedField = DBTableData then
    with TMemoEditorForm.Create(nil) do
    try
      DBMemoEditor.Text := DBTableData.AsString;
      ShowModal;
      DBTable.Edit;
      DBTableData.AsString := DBMemoEditor.Text;
    finally
      Free;
    end;
  end;
end;

Note 1: the "TMemoEditorForm" is a secondary form containing only one component: "DBMemoEditor" (TMemo).
Note 2: the "TMemoEditorForm" was removed from the "Auto-create forms" list in the Project Options dialog window.

Let's see what happens in the DBGrid1's KeyDown event handler:

1. When a user presses the ENTER key (we are comparing the Key parameter to the VK_RETURN virtual key code) [Key = VK_RETURN],
2. If the currently selected field in the DBGrid is our MEMO field (DBGrid1.SelectedField = DBTableData),
3. We create the TMemoEditorForm [TMemoEditorForm.Create(nil)],
4. Send the value of the MEMO field to the TMemo component [DBMemoEditor.Text := DBTableData.AsString],
5. Display the form modally [ShowModal],
6. When a user finishes with editing and closes the form, we need to put the dataste into the Edit mode [DBTable.Edit],
7. In order to be able to assign the edited value back to our MEMO field [DBTableData.AsString := DBMemoEditor.Text].

Note: if you are looking for more TDBGrid related articles and usage tips, be sure to visit: "TDBGrid to the MAX" tips collection.